Enemcee tech blog

Fetching max lights

I set out last night searching to understand how to query lights within 3dsmax scenes. Surprisingly, accomplishing this took less time than expected as I was able to get a very simple shader working in less than an hour. Lets take a look at how we query lights within the 3dsmax world, and where we can use this data.

3dsMax offers three specific semantic types for directx shaders to use with scene light data.
POSITION – For the light position,
DIRECTION – The light direction,
and LightColor – The light color.

Firstly, because we will be using both annotations and semantics, our light data is limited to ‘global’ declarations at the top of our fx files. Structs cannot have annotations, and local variables within functions cannot use semantics. Here’s a typical example of a vector linked to a light object within 3dsmax using semantics and annotations:

float3 lightPosition : POSITION <
	string UIName = "light position source";
	string Object = "omnilight";
	int RefID = 0;
> = {0,40,0};

This simple declaration pulls the position data from any light object within a max scene with a position (which means, any light). Lets break it down line by line and see which each value does.

float3 lightPosition : POSITION <

This first line is simply a declaration of a three-component vector. The semantic POSITION hints that this value will be, well, a position. The open carrot is the open-bracket equivalent for the value’s annotations.

string UIName = "light position source";

This declares the title of the UI element of this vector value. Because this value is tied to an object, instead of having a colorpicker like vectors usually have, the UI object will be a drop-down list of lights.

string Object = "omnilight";

This annotation is a key element of this value. The string ‘Object’ hints to 3dsmax that we’re interested in querying an object within the scene. The string is the name of the preferred default object within the scene to use for the value. If a light with the name “omnilight” exists within the scene, this vector’s value will be predisposed to be drawn from the position of the light.

If the preferred object is not present, or another light object wishes to be sourced, the UI allows the selection of which specific light should be used to draw a value from. If there are no lights within the scene to draw a position from, the default value is used.

int RefID = 0;

Adds a simple reference number to your light data. Aids in ensuring light data is updated properly within 3dsmax when handling multiple lights. Mostly associated with the “lightcolor’ semantic. Although I’ve not seen any clear-cut cases of this value being used, most examples have a unique refID for each light being queried.

> = {0,40,0};

The final line of the declaration specifies a default value for the variable. Keep in mind that all default values are in viewspace, while light directions and positions when queried from an object are in world space. I might be wrong here, but this seemed to be the case with my implementation.

How do we use these values? We can simply query these values to pass them through to our lighting functions. Pretty basic.

// lightDirection and lightColor,
//queried from an object perferably named 'fspot'

float3 lightDirection : DIRECTION <
 string UIName = "light direction source";
 string Object = "fspot";
 int RefID = 0;
> = {0,1,0};

float3 lightColor     : LightColor <
 string UIName = "light color source";
 string Object = "fspot";
 int RefID = 0;
> = float3(1,1,1);

// light function

float4 simpleDirectionalLight(float3 normal, float3 lightDir)
{

 float4 outputColor;

 float a = clamp(dot(lightDir, normal),0,1);

 outputColor.rgb = lightColor * a;
 outputColor.a = 1.0;

 return outputColor;

}

// my pixel shader

float4 ps_lightDir(vs_output in_vertData) : COLOR0
{
 float4 output_color = in_vertData.color;

 float3 curNormal = normalize(in_vertData.normal);

 output_color += simpleDirectionalLight(curNormal, lightDirection);

 return output_color;
}

This sample is omitting our vertex shaders and passes/techniques. Overall, it’s pretty simple to query lights within a 3dsmax scene. These features can be expanded upon by utilizing a custom interface written in maxscript, but this post is already quite long. I’ll see about covering that in a future post.

For reference of the 3dsmax specific semantics and annotations, check out this doc (in a zip file) from autodesk, which is a list of all unique and common 3dsmax semantics/annotations. (source)

Tags: 3dsmax, annotations, HLSL, lights, semantics